MS Access и 1С. Что, когда и зачем?

Публикация № 1039512

Программирование - Практика программирования

MS Microsoft Access MSOffice Office интеграция выгрузка

61
Об использовании MS Access в связке с 1С. Можно ли использовать продукты Office на сервере. Когда Access может быть полезен. Примеры работы и другое.

Немного слов

Время показало, что приложения для работы с  электронными таблицами, в том числе и Microsoft Excel, имеют потрясающие возможности для сбора, систематизации и анализа различных данных. Трудно представить бизнес, где бы не использовали этот инструмент. Вне зависимости от размера компании в ней обязательно используют электронные таблицы в том или ином виде.

Все те, кто работают с платформой 1С и решениями на ее основе не по наслышке знают, что Excel является чуть ли не главным инструментом бухгалтеров, аналитиков, финансистов и многих других специалистов.

Коллеги, Вы только вспомните сколько было сделано выгрузок из 1С в Excel! Сколько человеко-часов на это было потрачено!

Нет, нет! Excel ни в коем случае не является заменой учетных систем 1С, ведь назначение у них совершенно разное. Уберите оружие! Он скорее инструмент локального пользования для более гибкой обработки данных, ведь в 1С это не всегда сделать также просто, как в Excel.

Но если все так хорошо, то почему статья будет про Access? Неужели им кто-то еще пользуется? И на самом деле пользуется! 

Excel vs. Access

Эпичной битвы не будет! Мы просто сравним два отличных инструмента по 9 критериям и опишем ситуации, когда Access может быть более подходящим вариантом.

Критерий Excel Access
Назначение Создание графиков, диаграмм и различных моделей данных. Приложение базы данных для сбора и сортировки данных.
Использование Построение финансовых, статистических и других моделей, а также возможность проверки данных при вводе. Сбор, сортировка и изменение информации в базах данных.
Размер хранилища Имеет ограничения по количеству строк (1 048 576) и столбцов (16 384), а также другие ограничения. Подробнее смотреть здесь. Ограничения на макс. размер базы (2 ГБ) и другие. Подробнее смотреть здесь.
Возможность доработки Очень просто. Это может сделать любой пользователь Excel, конечно, если дело не касается макросов или других специфичных вещей. Сложно, поскольку требуются знания по построению баз данных и других особенностей.
Применимость Больше всего подходит для анализа данных (финансовых, статистических или любых других). Больше подходит для хранения данных. Ориентировано больше на малый бизнес.
Изучение Прост в изучении. Тяжелее в изучении по сравнению с Excel.
Реляционный или линейный Не реляционное хранилище данных. Для хранения используется реляционная модель.
Знание программирования В большинстве случаев знания программирования не нужны. Знания программирования обязательны для работы с базами данных Access.

И так, Access меньше ограничен в объемах выгрузки данных и позволяет строить реляционную модель хранения информации. Кроме того, можно делать произвольные SQL-запросы к таблицам для обработки данных. Во всем остальном Excel удобнее и эффективнее. Это если смотреть общую информацию, поэтому поклонников Access прошу не идти на несанкционированный митинг в комментариях! Тем более никто не мешает подключиться к базе Access из Excel и работать в последнем.

Таким образом, когда нужно выгрузить информацию из базы 1С в большом объеме и при этом у конечного потребителя нет навороченной СУБД, или просто стандарт работы через Access, или же есть реализованная на нем бизнес-логика, то почему бы не использовать его? Также иногда нужно обойти ограничение Excel в 1 миллион строк и выгрузить данные одним набором. В последнем случае база данных Access также может быть хорошим выбором.

Конечно, вместо Excel или Access есть масса других вариантов, но в зависимости от требований они не всегда могут подходить:Да начнется холивар

  • CSV-файлы - их трудно анализировать, да и подходит это больше для последующей загрузки в другой источник данных.
  • База SQL Server / PostgreSQL - отличный вариант, вот только не все конечные пользователи могут позволить себе настройку этого ПО.
  • Разбить выгрузку Excel на несколько файлов? Отлично! Попробуйте собрать отчетность из 15 файлов Excel по 1 миллиону записей, тогда и поговорим!
  • И др.

Далее поверхностно пробежимся по вопросу лицензирования и наконец-то перейдем к разработке.

Немного про лицензии

Этот вопрос очень важный, поскольку можно здорово напортачить, от чего в будущем могут быть проблемы из-за нарушения лицензионного соглашения Microsoft на их ПО. Дело тут вот в чем.

Выгрузка или другие действия в 1С должны выполняться на стороне сервера 1С, т.к. только там мы можем работать с запросами, таблицами значений или с системой компоновки данных. Конечно, есть еще толстый клиент и файловые базы, но сейчас они не представляют особого интереса, ведь тонкий клиент более предпочтительный вариант для прикладных решений. А для файловых баз проблема лицензирования офиса вообще не стоит, т.к. обычно все кто с этой базой работают уже имеют установленный офисный пакет. Получается, что для того, чтобы сервер 1С мог работать с базами данных Access нужно выполнить одно из следующих действий на сервере 1С:

Самым простым вариантом выглядит установка полного пакета приложения MS Access на сервере, но это сильно нарушает лицензионное соглашение. В этом случае потребуется покупка лицензий на Office не только для сервера, но и клиентские лицензии для всех пользователей, которые работают с этим сервером. В нашем случае для всех, кто работает в 1С на этом сервере. А если пользователей 1000? И их становится все больше? Докупать лицензии? Это будет не дешево. В некоторых случаях лицензия может вообще запрещать такое развертывание, но на подробностях уже не будем останавливаться.

Второй вариант - это установка только ODBC-драйвера в пакете Microsoft Access Database Engine 2016 Redistributable. Да, это будет работать! Access устанавливать не нужно, а мы сможем работать с базой данных Access через ADO-соединение. Но и тут не все просто! Если перейти по ссылке и посмотреть детальную информацию, то там черным по белому написано, что этот пакет не может использоваться для:

  • Для замены Ace (нас это сейчас не интересует).
  • Для замены Jet OLEDB (из 1С тоже можно работать через Jet с базами Access, но это уже другая история).
  • Как замена основных систем управления базами данных, электронными таблицами или документами.
  • И самый главный пункт - использоваться как системная служба или программа серверной части приложения.

Фактически, этот пакет предназначен для клиентских компьютеров, которые подключаются к различным источникам данных

Третий вариант - установка Microsoft Access 2016 Runtime. Согласно информации на странице, для установки и распространения не требуется покупка дополнительных лицензий, т.к. этот пакет содержит лишь среду выполнения, которая используется для запуска уже готовых решений. Средства разработки в ней отсутствуют. При этом в состав пакета также входит установщик ODBC-драйвера, который нам и нужен.

На практике видел использование второго и третьего варианта, причем аудит от Microsoft не выявлял в этом случае никаких нарушений. Возможно, установка Microsoft Access Database Engine 2016 Redistributable формально и может являться нарушением соглашения, но по факту его никто не проверяет.

Все вышесказанное относится и к другим продуктам MS Office, в том числе и Excel, Word и т.д. Интересная информация по лицензированию есть здесь, можете прочитать там про "Access Runtime".

Нашли ошибку или не согласны что лицензирование работает именно так? Пишите в комментариях!

Простые примеры

В основном мы сосредоточимся на задачах выгрузки данных в Access. Операции загрузки также возможна, но она всегда достаточно простая и очень сильно завязана на условиях задачи (что и куда загрузить, как преобразовывать данные из базы и т.д.). Приведу лишь небольшой пример загрузки данных.

ФайлБазы = "D:\Каталог баз\ПримерБазы.accdb";

// Инициализация подключения к базе
СтрокаПодключения = "Driver={Microsoft Access Driver (*.mdb, *.accdb)};DBQ=" + ФайлБазы;
Connection = Новый COMОбъект("ADODB.Connection");	
Connection.Open(СтрокаПодключения);

// Формируем команды чтения данных из таблицы "Выгрузка_результата_компоновки"
Command = Новый COMОбъект("ADODB.Command");
Command.ActiveConnection = Connection;
Command.CommandText = "Select * FROM Выгрузка_результата_компоновки";
Command.CommandType = 1;
RecordSet = Command.Execute();

// Считываем все поля и выводим пользователю
ЗначенияСтрокой ="";
Пока RecordSet.EOF() = 0 Цикл
	
	Для НомерПоля = 0 по  Recordset.Fields.Count - 1 цикл
		ЗначенияСтрокой = ЗначенияСтрокой + " " + Recordset.Fields(НомерПоля).Value;
	КонецЦикла;
	
	Сообщить(ЗначенияСтрокой);		
	ЗначенияСтрокой = "";
	
	RecordSet.MoveNext();
	
КонецЦикла;

// Освобождаем ресурсы
RecordSet.Close();
Connection.Close();

Все просто - создаем соединение с базой данных Access через ADO, создаем команду чтений данных в виде набора и обрабатываем его. После освобождаем ресурсы.

С выгрузкой данных все куда интересней, потому что проблемы сложнее:

  1. ODBC-драйвер не позволяет создать пустую базу. Тут либо иметь уже готовый файл с нужными таблицами или придумывать альтернативный вариант (что и было сделано, но об этом позже).
  2. При выгрузке всегда одного набора данных задача упрощается, но что если нужно выгружать каждый раз разные наборы. Например, нужно выгружать отчет на СКД и учитывать, что настройки (выводимые поля) пользователь может изменять. То есть нам нужно научиться создавать таблицы в Access, сопоставляя типы 1С с доступными типами MS Access.
  3. Нужно учесть ограничения базы Access на различные типы, а также на сам ODBC-драйвер. Например, что выгрузка в Access не поддерживает даты меньше 1753 года, если используется ODBC-драйвер.
  4. Также необходимо учитывать максимальный размер базы данных в 2 ГБ. Тут в качестве решения может быть настройка максимального количества выгружаемых записей для одной базы. В случае необходимости выгрузка будет выполняться в несколько порций.

То есть на практике нужно быть готовым к выгрузке произвольных наборов данных. которые в 1С могут быть представлены таблицей значений, запросов или результатом компоновки данных отчета. Если бы этих проблем не стояло, то алгоритм выгрузки был бы примерно такой.

Запрос = Новый Запрос;
Запрос.Текст = 
	"ВЫБРАТЬ
	|	&ТекущаяДата КАК Дата,
	|	""Привет из Access"" КАК Строка";	
Запрос.УстановитьПараметр("ТекущаяДата", ТекущаяДата());
ТаблицаИсточник = Запрос.Выполнить().Выгрузить();

// Подготовленная база Access для выгрузки
ПутьКБазе = "C:\Access\ПростаяВыгрузка.accdb";

СтрокаПодключения = "Driver={Microsoft Access Driver (*.mdb, *.accdb)};DBQ=" + ПутьКБазе;
СоединениеКБазе = Новый COMОбъект("ADODB.Connection");	
СоединениеКБазе.Open(СтрокаПодключения);

ИмяТаблицы = "ПростаяВыгрузка";
Запись = Новый COMОбъект("ADODB.RecordSet");	
ТекстЗапроса = "SELECT * FROM " + ИмяТаблицы;	
Запись.Open(
	// Текст запроса 
	ТекстЗапроса, 
	// Соединение с базой
	СоединениеКБазе,
	// Указывает тип курсора, используемого в записей объекта.
	// CursorType (https://docs.microsoft.com/ru-ru/sql/ado/reference/ado-api/cursortypeenum?view=sql-server-2017)
	// 1 = adOpenKeyset. Использует курсор набора ключей. 
	1, 			  
	// Тип блокировки
	// LockTypeEnum (https://docs.microsoft.com/ru-ru/sql/ado/reference/ado-api/open-method-ado-recordset?view=sql-server-2017)
	// 3 = adLockOptimistic (Указывает, оптимистической блокировки, записей.)
	3
);

// Добавляем записи в таблицу базы Access
//	В исходном файле первая колонка содержит дату,
//	а во второй сохраняем строку.
Для Каждого СтрокаТаблицы Из ТаблицаИсточник Цикл
	
	Запись.AddNew();
	Запись.Fields(0).Value = СтрокаТаблицы.Дата;
	Запись.Fields(1).Value = СтрокаТаблицы.Строка;
	Запись.UpDate();
	
КонецЦикла;	

СоединениеКБазе.Close();
СоединениеКБазе = Неопределено;

Но вернемся все же к реальным требованиям. Для упрощения разработки и сопровождения сделаем прокси-функцию, которая позволит выгружать в Access таблицы значений, запросы и результаты СКД.

Прокси, прокси, прокси

Начнем с описания что в итоге нужно получить. Интерфейс выгрузки будет представлен тремя функциями:

  • ВыгрузитьТаблицуЗначений(КаталогВыгрузки, ИсточникДанных)
  • ВыгрузитьЗапрос(КаталогВыгрузки, ИсточникДанных)
  • ВыгрузитьРезультатКомпоновки(КаталогВыгрузки, СхемаКомпоновкиДанных, Настройки)

Примеры работы с ними ниже под спойлером.

 
 Примеры выгрузки в Access

Но как были решены все те проблемы, о которых говорилось выше? Ответим по порядку!

Создать базу данных можно двумя способами:

  1. Если на клиенте есть установленный MS Access, то базу можно создать с его помощью, в т.ч. и инициализировать нужные таблицы. Так мы получим шаблон базы данных нужной структуры, а позже его уже можно передать на сервер и работать с ним с помощью ODBC.
  2. Другой вариант - можно создать пустой файл базы данных Access без таблиц и сохранить его, например, в общий макет. На сервере для создания базы данных используем данные макета, а создание таблиц выполняем с помощью ODBC.
 
 Инициализация базы данных Access

Но что на счет описания типов полей таблицы и как его получить для типов платформы 1С? В этом случае нужно обрабатывать несколько ситуаций:

  • Тип значения поля составной.
  • Тип значения "Строка" как с указанной длиной, так и неограниченная.
  • Числовой тип разной длины и разрядности.
  • Тип булево.
  • Тип дата.
  • Ссылочные типы.
  • Остальные типы, включая служебные.

Общее соответствие типов можно сделать такое.

Тип 1С Тип Access
Составной тип (может включать примитивные типы и ссылочные) CHAR(255), в случае превышения длины строки значение будет обрезаться.
Строка CHAR(<Размер>). Размер определяется длиной строки в описании типа (макс. длина 255). Если это значение - представление какой-либо ссылки, но нужно получить длину поля представления (код, наименование) и присвоить его длине строки в Access.
Число Если у числа явно указано, что оно может быть только целым, то используем "INTEGER". В остальных случаях "DOUBLE" с различной длиной и разрядностью дробной части.
Булево BIT
Дата DATETIME
Ссылочные и другие типы CHAR(<Размер>). Длину указываем как 150 символов по умолчанию.
 
 Получение описания полей Access для таблицы значений 1С

По поводу проверки на ограничения типов, например для дат, можно использовать такие функции.

 
 Проверка даты на корректность

Ограничение базы данных Access на 2 Гб можно обойти, разбивая ее на несколько файлов. Тут либо разбивать по размеру базы, каждый раз проверяя текущий размер файла базы, либо задав ограничение на количество записей.

Полная реализация выгрузки с примерами доступна в репозитории на GitHub - "1C-Plus-MSOffice", где постепенно будут добавляться различные примеры, алгоритмы и инструкции по работе с продуктами MS Office из 1С. Планируется добавить такой функционал и инструкции:

  • Выгрузка в Excel и Word на сервере без использования MS Office.
  • Описание штатных возможностей платформы для выгрузки в Excel.
  • Оптимизация выгрузки больших массивов данных в Excel (минимальное использование памяти и др.).
  • Описание формата файлов документов Office.
  • Использование Outlook и шифрования в нем.
  • И др.

Содержимое репозитория не является готовым решением, а лишь помогает, объясняет и ускоряет разработку. Весь материал лишь признан помогать, а не выполнять работу за Вас (разработчиков).

Замечания, предложения, issues и pull-request'ы приветствуются!

После всего

Мы рассмотрели использование Access для выгрузки данных из баз 1С, некоторые нюансы лицензирования и небольшие примеры выгрузки и загрузки данных. Также продемонстрированы прокси-функции для выгрузки таких типов данных 1С как таблица значений, запрос и результат компоновки данных. Смотрите в репозиторий "1C-Plus-MSOffice", там будут добавляться новые функции, инструкции и различные фичи при работе с приложениями MS Office.

Спасибо, что что Вы все еще здесь! :)

Удачи!

Другие ссылки

61

См. также

Специальные предложения

Комментарии
Избранное Подписка Сортировка: Древо
1. blackhole321 1004 09.04.19 11:32 Сейчас в теме
Зачем файловая СУБД, если есть SQL Server Express?
YPermitin; +1 Ответить
2. YPermitin 3046 09.04.19 11:36 Сейчас в теме
(1) незачем.

Кроме тех случаев, когда ее нет :)
Не каждый пользователь модет использовать SQL Server у себя на машине.

Тем более Access это не только файловая СУБД.
SeiOkami; +1 Ответить
3. e][tend 09.04.19 12:00 Сейчас в теме
Эх, Юрий, вашу бы статью да полгода назад, тогда толковых примеров по работе с Access не нашел.))
Да и вообще, читаю ваши статьи с интересом.
Как раз на том проекте делал выгрузку отчета на СКД в файл базы данных Access.
Столкнулся тогда с проблемой, преобразования дат, если компьютер на котором происходит выгрузка, имеет английскую локаль, то и даты нужно писать в файл в "иностранном" формате. Не учел этот момент изначально, долго искал потом в чем проблема.
YPermitin; +1 Ответить
4. YPermitin 3046 09.04.19 12:19 Сейчас в теме
(3) спасибо на добром слове! :)

Будет интерес - будут и статьи.

Знал бы - написал бы полгода назад :)))
5. s_vidyakin 09.04.19 12:27 Сейчас в теме
А зачем все эти заморочки? Тогда проще поставить любую фришную СУБД, хоть sqlite3, к ней есть бесплатные клиенты. Хоть монго, хоть постгрес, хоть mySql
VladC#; oneman@yandex.ru; YPermitin; +3 Ответить
6. YPermitin 3046 09.04.19 12:32 Сейчас в теме
(5) все так. Это просто, есди Вы разработчик.

А если пользователь / заказчик работает в Access и у него уже сложилась целая экосистема на нем?

Плюс при работе в Access есть всем известные инструменты работы с данными, конструкторы и т.д. Не так просто будет переучить быстро сотрудника использовать новый инструмент, вместо старого.
SeiOkami; blackhole321; +2 Ответить
7. Sherman 11 09.04.19 13:30 Сейчас в теме
Я бы сравнивал Access с 1С предприятием, но никак не с Excel.
В бытность, попадались неплохие реализации потребностей на Access...
blindcat2006; YPermitin; +2 Ответить
9. YPermitin 3046 09.04.19 14:28 Сейчас в теме
(7) Access хорош.

В статье сравнение с Excel не в том плане что лучше, это все же разные инстументы. Там именно различия для пользователей показать и почему Access иногда лучше себя ведет, чем Excel.
8. ellavs 502 09.04.19 14:04 Сейчас в теме
Отличная статья. Честно говоря, пока не могу для себя придумать, для чего можно было бы использовать выгрузку в Access из 1С (в плане именно для пользователей). Подумался такой вариант - если пользователь захочет какой-то фрагмент базы себе получить, а 1С у него нет (не у всех же есть личный 1с ключ для работы дома :), да и вообще не будешь же всем пользователям экземпляры базы отдавать, тут уже можно и под закон о ПДн попасть), но есть Access (у всех наших пользователей установлен Office), и он хочет "получить красиво", а не просто список таблиц (для этого и Excel бы подошел), то можно выгрузить в Access часть нужных данных, наваять пользователю красивых форм, чтобы он даже не подумал залезть непосредственно в таблицы, и в таком виде отдать. Особенно хорошо, что Access-то пользователю на самом деле и не нужен, можно сделать автономный файл + Runtime и всё.
Оффтоп: сами мы используем один сумасшедший вариант - есть на сервере MS SQL база (телефонный справочник), из которого веб-приложение тянет данные, а редактор у этой базы на Access на клиентской машине (который как источник данных использует MS SQL) с формами для работы с данными.
YPermitin; +1 Ответить
10. YPermitin 3046 09.04.19 14:30 Сейчас в теме
(8) вариант не сумашедший :) У вас все в порядке =D

А так да, внешние таблицы в Access это очень мощная штука.
27. v3rter 12.04.19 09:37 Сейчас в теме
(8) Лет 10 назад мне попадались очень даже работоспособные аналоги торговых, производственных программ и даже бухгалтерии 7.7 на связке Access + SQL (связанные таблицы), прекрасно работали. Удобно в этой связке то, что "серверная сторона" - структуры данных, справочники, запросы - пишутся очень быстро и работают потом шустро, а неудобна "клиентская сторона" - прежде чем в форму можно будет пустить реального пользователя, придется изменить несколько десятков ее параметров и написать почти столько же обработчиков для каждого интерфейсного "чиха".
В общем, проблема будет в том, что далеко не все смогут себе позволить содержать целого программиста VBA )
YPermitin; +1 Ответить
11. 3vs 09.04.19 15:07 Сейчас в теме
Юрий, а Вы такие же эксперименты с LibreOffice не делаете, а то у нас сейчас модно "отечественные продукты"
использовать?
Опять же - кроссплатформенность.
user-z99999; YPermitin; +2 Ответить
12. YPermitin 3046 09.04.19 15:22 Сейчас в теме
(11) сделать, конечно можно.

Для свободного офиса делал только конвертации форматов файлов и дорабатывал БСПшные модули для печатных форм.

Пока все же MS Office у большинства установлен не смотря на последние тенденции. Но если станет актуальным и востребованым, то появится репо на GitHub "1C-Plus-LibreOffice" :)
13. 3vs 09.04.19 18:51 Сейчас в теме
(12)Думается, когда 1С поднимется на помидорах корпоративных лицензиях, встанет вопрос, а не приобрести ли свою операционную систему на базе линукса.
Хорошо смотрится в этом плане Альт линукс, (www.basealt.ru), нужные сертификаты есть, свой репозиторий есть, сервер и рабочая станция есть сертифицированные, опять же может работать на отечественном Эльбрусе.
Самое то для полной интеграции с 1С!
Тогда и увязка с LibreOffice потребуется. :-)
YPermitin; +1 Ответить
14. YPermitin 3046 09.04.19 19:02 Сейчас в теме
15. 3vs 09.04.19 19:11 Сейчас в теме
(14)Ну почему же ужасть! :-)
IBM покупает Red Hat за 34 млрд долларов
www.ixbt.com/news/2018/10/29/ibm-red-hat-34.html

Логика развития диктует, у нас придут к тому же.
Своего Майкрософта как-то у нас не состоялось.
acanta; YPermitin; +2 Ответить
16. YPermitin 3046 09.04.19 19:48 Сейчас в теме
(15) 1C:OS 8.3.

Требует активации через USB-ключ.
Скрипты на языки 1С.
Стоимость лицензии...
17. 3vs 09.04.19 20:37 Сейчас в теме
(16)
1C:OS 8.3.

Скорей 1C:OS 9 какая-нибудь!
Зато всё из коробки, своё родное, жёлтенькое! :-)
22. A_Max 17 10.04.19 12:02 Сейчас в теме
(17) Лучше готовые docker контейнеры. Хотя вариант со своей готовой сборкой дистрибутива тоже неплоха.
23. YPermitin 3046 10.04.19 12:09 Сейчас в теме
(22) хватит им подсказывать!
18. anosin 27 09.04.19 21:58 Сейчас в теме
(13)
И ее в коробке с юсби ключами продавать будут? ;)
думаю что их "договоренность с сами знаете с кем" не позволит им это выпускать.
YPermitin; +1 Ответить
19. YPermitin 3046 09.04.19 22:08 Сейчас в теме
(18) договоренность с тем, чье имя нельзя произносить вслух? :)
20. 3vs 10.04.19 06:20 Сейчас в теме
(18)После 2024 года много чего может случиться...
Товарищ Назарбаев тоже вон устал!
А товарищ Медведев на посту вполне себе может и допустить,
время вперёд двигал, милицию в полицию переименовал, а это мелочи по сравнению с такими свершениями!

Я бы на месте товарища Нуралиева задумался над беспризорностью Альт линукса.
21. YPermitin 3046 10.04.19 10:09 Сейчас в теме
24. =Kollega= 1 10.04.19 18:47 Сейчас в теме
RecordSet = Новый COMОбъект("ADODB.RecordSet");
RecordSet = Command.Execute();

А зачем создавать com объект чтобы сразу его переписать?
YPermitin; +1 Ответить
25. YPermitin 3046 10.04.19 19:10 Сейчас в теме
(24)
RecordSet = Command.Execute();


Очепяточка вышла :)
26. YPermitin 3046 10.04.19 19:39 Сейчас в теме
(24) Исправил в публикации. Спасибо!
28. EliasShy 47 23.07.19 07:57 Сейчас в теме
Много лет назад, когда 1С "дружила" с Microsoft был Addin для MS Office, который позволял получать доступ к 1с из Office. Решение было сырое, и почему-то быстро его прикрыли.

Сейчас, когда технические возможности позволяют взаимодействовать между системами через сервисы, очень не хватает подобного, простого механизма.
YPermitin; +1 Ответить
29. AllexSoft 23.07.19 12:55 Сейчас в теме
В статье не описано 2 очень важных нюанса, а именно
1. драйвера ODBC х32 и х64 не совместимы! представим себе ситуацию, у вас на сервере 1С Сервер х64, соответственно драйвер OBDC он то же х64 будет использовать. Допустим формируем мы на сервере данные и кладем им в расшаренную папочку, шлем по почте и тд файлики акцесса, а у пользователей офис на рабочих машинках x32 и они ничего открыть не смогут, после того как x64 акцессом или драйвером ODBC x64 записался файл его на 32х разрядном офисе не открыть. Если у клиента зоопарк с версиями офисов то могут быть существенные проблемы! Для нас это оказалось критично, пришлось отказаться хранить что либо в акцессе.

2. если вам нужно перезаписывать данные в БД акцесса то он по умолчанию не освобождает место. Допустим мы хотим обновлять одну из таблиц БД акцесс каждую ночь регламентной выгрузкой. Собственно очищаем таблицу, записываем на ее место точно такую же, но объем БД вырос. Если объем таблиц несколько сотен мб вы за короткое время достигаете лимита, хотя самих данных у вас может быть не много. Есть функция освобождения свободного места, после удаления какого либо объема данных ее лучше вызывать.

Пробовали использовать как прокси-таблицу выгрузки аналитики продаж, что бы пользователи подключались туда через Excel или акцессом и строили сводные отчеты, в итоге только убили время на выяснение косяков, по типу что в п1. Мы кстати подключали через внешние источники данных, все норм подключается, но с конвертацией типов (кажется дробных чисел), в акцесс были проблемы с типом DOUBLE. В итоге плюнули и сделали все на MS SQL Server.
YPermitin; acanta; +2 Ответить
30. YPermitin 3046 23.07.19 13:02 Сейчас в теме
(29) все так. И ваши истории мне близки. Не во всех случаях Access удачный вариант.

А если есть выбор между SQL Server и Access, то вообще в сторону последнего можно не смотреть.
AllexSoft; +1 Ответить
31. AllexSoft 23.07.19 13:17 Сейчас в теме
(30)
А если есть выбор между SQL Server и Access, то вообще в сторону последнего можно не смотреть

согласен полностью!
И тут не очень видится применение акцесса как такового, ибо если компания с несколькими десятками юзеров в 1С будет иметь скорее всего 1С Сервер, а значит и СУБД либо MS SQL Server или PostgeSQL. Если компания мелкая, а есть ли у нее тот объем данных которые надо выносить во внешние таблицы и нельзя решить с помощью отчетов 1С.
Получается что акцесс как средство выгрузки актулен в основном тем кто имеет уже готовую систему на акцесс и ее надо просто продолжать поддерживать. Ну либо с точки зрения загрузки из акцесса, за частую бывает что экспорт из различных программ есть именно в бд акцесс, например я столкнулся что счетчики посетителей имеют выгрузку в акцесс.
Оставьте свое сообщение